person: KDF_1409_Kelsava, 3

!var int kelsavaFocusDay;

info: Exit

info: heyYou
>Wer bist du?
<Mein Name ist Kelsava, Magier des Eises und Meister der Runen.
<Was kann ich für dich tun?

info: teachLightRune
conddia: KDF_1404_Uysal, teachRune
>Uysal schickt mich.
>Er sagt, du kannst mir einen Runenstein geben.
<Soso, einen Runenstein? Wofür brauchst du denn einen?
>Ich soll eine Lichtrune herstellen.
<Weißt du denn auch, welche Elemente du noch brauchst?
>Einige Goldstücke.
<Sehr gut. Dann nimm diesen Runenstein.
<<ItMi_RuneBlank, 1
<Leg ihn zusammen mit dem Gold in den Runentisch. Die Essenz wird dann in den Stein übergehen.

info: gotRune
conditem: ItRu_Light, 1
>Ich habe die Rune hergestellt!
<Sehr gut! Dann geh direkt zu Uysal zurück! Er wird dir dann weitere Runen beibringen.
$EXP 150

info: giveMaterial
conddia: KDF_1404_Uysal, doSth
>Du sollst mir Material geben.
<Was brauchst du denn und vor allem: Wofür?
>Ich brauche Zutaten für vier Feuerpfeil-Runen. Ich soll sie herstellen und unter den Novizen verteilen.
<Sehr gut. Langsam wird es erst, nicht?
>Stimmt. Ich glaube zwar nicht, dass die Schwarmagier in nächster Zeit angreifen, aber..
<Vorsicht ist besser als Nachsicht. Das stimmt.
<Gut, hier hast du die Zutaten.
<<ItMi_Sulfur, 4
<<ItMi_RuneBlank, 4
<<ItSc_Firebolt, 4
<Dann mach dich mal an die Arbeit!
$LOGMISS runesForNovices, Kelsava hat mir die Materialien gegeben. Also los, an die Arbeit.

info: investigations
conddia: KDF_1403_Rayan, whatNow
>Du untersuchst das Phänomen?
<Das ... Phänomen?
<Achso, du meinst die Störungen in den magischen Feldern.
<Oder den Linien?
<Siehst du, da fängt es schon an.
<Sind es Linien oder Felder? Oder etwas ganz anderes?
>Verzeihung?
<Okay, ich sollte von vorne anfangen. Was weißt du denn bisher?
>Nur, dass es ein Erdbeben gab und das Gefüge der Magie dadurch gestört wurde. Oder umgekehrt.
<Gut, dann bist du nicht weiter als ich.
<Ich würde gerne ein Experiment mit dir anstellen. Keine Sorge, du solltest keinen Schaden erleiden. Denke ich wenigstens...
<Es ist schwer, neutrale Aussagen zu Veränderungen an Zaubern zu treffen.
<Verursacht ein Feuerball jetzt mehr Schmerzen oder nicht? Brennt sein Feuer heißer?
<Das ist subjektiv und nicht messbar. Selbst wenn ich dich einfriere, könnte ich messen wie lange, aber nicht, welche Auswirkungen das auf deinen Körper hat.
<Oder um es genauer zu sagen: Ich habe keine Vergleichswerte. Nur bei einem Zauber...
>Jetzt spucks schon aus!
<Okay. Kennst du dich mit Teleportationszaubern aus?
>Grob, ja. Auf dem Festland benutzen wir etwas ähnliches, aber... Frag mich bitte nicht, wie die funktionieren.
<Ja, davon habe ich gehört. Das Prinzip ist ganz ähnlich. Wir wissen auch nicht genau, auf welche Art unsere Teleportationsrunen ablaufen. Wir kennen nur das Endergebnis.
<Sobald der Zauber abgeschlossen ist, wirst du in Nullzeit von einem Ort zum anderen versetzt. Die Sanduhr schafft nicht ein einzelnes Korn.
<Sollte sich etwas drastich geändert haben, können wir es so messen. Ich werde dir die Rune zum Kloster geben.
<Und Sellan eine Sanduhr. So können wir klären, ob etwas anders abläuft.
>Vorausgesetzt, ich komme überhaupt beim Kloster aus.
<Was auch immer passiert, wir werden es feststellen.
<Hier, die Rune. Viel Erfolg!
<<ItRu_TeleportMonastery, 1
!usedTeleportIM = FALSE;
$LOGMISS magicFabric, Kelsava hat mir eine Teleportrune gegeben. Er sagt, damit könne er genau messen, ob sich etwas an der Magie geändert habe. Hoffentlich geht das gut... Ich habe keine Lust, in einem Felsen zu landen.

info: teleWentWrong
condcode: usedTeleportIM == TRUE
conddia: investigations
>Das ging ziemlich daneben.
<So könnte man das auch sagen. Wo bist du ausgekommen?
>Du weißt, dass das schiefgegangen ist?
<Naja... Sellan fragte schon nach, ob ich dir die falsche Rune gegeben habe.
>Ah...
>Ich bin kurz vor dem Pass zum alten Minental ausgekommen.
<Also nur ein Stückchen daneben...
<Hoffen wir, dass das nicht zur Gewohnheit wird.
$MISSUCC magicFabric
$LOGMISS magicFabric, Kelsava weiß Bescheid. Mal sehen, was wir aus diesen Ergebnissen machen.
$EXP 300
<Gut. Da wäre allerdings noch...
>Noch ein Test?
<Nicht ganz. Während du ... unterwegs warst, kam ein Bote aus der Stadt und berichtete, dass es auf einigen Teilen der Insel zu weitaus größeren Problem kommt.
<Offenbar hat das, was unsere Magie stört, auch dafür gesorgt, dass die Toten aus ihren Gräbern steigen.
>Meinst du Zombies oder Geister?
<Ihr habt auf dem Festland wohl mit so einigem zu tun... Er sprach nur von Zombies. Hoffentlich kommt da nicht noch mehr.
<Wie auch immer. Der Hohe Rat hat sich beraten und vorgeschlagen, einen Kriegsrat zu bilden. Denn es betrifft wahrscheinlich die ganze Insel.
<Und wir können dem nur gemeinsam begegnen. Ich gehe davon aus, dass die Paladine dem zustimmen werden und versuchen, alle Fraktionen an einen Tisch zu bringen.
<Der Hohe Rat hat mich abgestellt. Immerhin habe ich unsere bisherigen... Forschungen angestellt. Und ich würde wirklich gerne teilnehmen.
<Ich habe nur noch auf dich gewartet.
>Auf mich? Wieso das denn?
<Ich würde dich gerne mitnehmen. Du bist nicht in den Mustern festgefahren, in denen die Menschen auf dieser Insel denken.
<Oder denkst du, dass dieser ewige Kampf zwischen den Fraktionen zielführend ist?
>...
<Denke ich auch. Also, was hälst du davon? Begleitest du mich?
>Natürlich. Wann brechen wir auf?
<So schnell wie möglich. Der Hohe Rat weiß Bescheid und dich von sämtlichen Verpflichtungen entbunden.
<Wir treffen uns im Rathaus. Die Wache wird dich reinlassen. Morgen abend findet die Konferenz statt.
!dayConference = Wld_GetDay();
!AI_PrintS_Ext (self, "Komm morgen um 19 Uhr zum Rathaus!", RGBA(0, 153, 0, 0));
!changeRoutineConference();
$STARTMIS Conference
$LOGMISS Conference, Die Paladine in der Stadt wollen einen Kriegsrat abhalten. Kelsava wird als Gesandter des Klosters teilnehmen und möchte mich mitnehmen. Mal schauen, was dabei herauskommt...

info: foundNeutralPlace
condcode: foundNeutralPlace == TRUE
condcode: toldNeutralPlace ==  FALSE
>Ich habe einen Ort für uns gefunden!
<Wirklich? Das ist sehr gut!
<Wo ist denn dieser Ort?
>Ein Stückchen hinter der Taverne, ganz in der Nähe vom großen Bauernhof gibt es eine alte...
>Ja, was ist das eigentlich? Eine Burg? Naja, nicht ganz.
>Da gibt es einen Minenschacht, mit ein paar Gebäuden.
>Der Komplex liegt auf einer Klippe, nur ein schmaler Weg führt da hinauf. Ist also im Notfall gut zu verteidigen.
>Viel Platz gibt es auch, insgesamt sind da zwei Türme und noch eine Hütte.
<Das klingt hervorragend. Bestens geeignet.
<Ich gebe den anderen Bescheid. Sagen wir, wir treffen uns in zwei Tagen!
$LOGMISS findNeutralPlace, Kelsava war begeistert. Er wird den anderen Bescheid geben und hat vorgeschlagen, dass wir uns in zwei Tagen treffen.
$MISSUCC findNeutralPlace
$EXP 350
>Da wäre noch etwas anderes...
<Ja? Was denn?
$IF Npc_KnowsInfo(hero, VLK_4007_Fyneia_newJob)
>Bei den Söldnern gibt es eine Alchemistin. Ihr Name ist Fyneia.
$ELSE
>In der Stadt gibt es eine Alchemistin. Ihr Name ist Fyneia.
$ENDIF
<Und?
>Sie hat ein altes Rezept gefunden und ein Öl hergestellt, welches die Kampfkraft gegen Untote stärkt.
<Das hört sich... interessant an. Funktioniert es?
>Ich bin mir nicht sicher. Aber ich würde sie gerne einladen. Ich denke, ihre Fähigkeiten könnten sich als nützlich erweisen.
<Das denke ich auch.
<Wenn du ihr vertraust, sag ihr Bescheid!
$STARTMIS firstNeutralMeeting
$LOGMISS firstNeutralMeeting, Der Ort steht fest. In zwei Tagen wollen wir uns zum ersten Mal treffen. Ich bin gespannt. Ich hoffe sehr, dieses Treffen wird besser als der Kriegsrat in der Stadt. Vorher sollte ich Fyneia noch Bescheid sagen.
!toldNeutralPlace = TRUE;
!Npc_ExchangeRoutine(self, "NEUTRALFIRST");
!Npc_ExchangeRoutine(KDW_14009_Thirala, "NEUTRALFIRST");
!Npc_ExchangeRoutine(BAU_241_Zaphina, "NEUTRALFIRST");

info: letsFindBook
condcode: Npc_GetDistToWP(self, "NW_MONASTERY_RUNEMAKER_02")
condcode: Npc_GetTrueGuild(hero) == GIL_NOV
>Wie gehen wir vor?
<Naja, die Bibliothek ist nicht sonderlich groß, aber es sind trotzdem einige Bücher.
<Ich habe mir aus dem Privatbesitz der Magier noch ein paar Bücher geben lassen und werde diese durchschauen.
<Es wäre gut, wenn du die Regale durchsehen könntest.
!activateBookshelfes();
$LOGMISS findLegendBook, Kelsava möchte, dass ich die Bücherregale nach der Legende durchsuche. Das kann ja heiter werden...

info: foundTheBook
conditem: ItWr_LegendBook
>Ich habe das Buch gefunden!
>>ItWr_LegendBook, 1
<Sehr gut. Und du bist dir sicher, dass es das richtige ist?
>Altes Buch, kaum lesbar, viele Legenden.
<(lacht) Klingt gut. Ich werde den passenden Text raussuchen.
<Wir sehen uns dann beim Treffen!
$EXP 200
$MISSUCC findLegendBook
$LOGMISS findLegendBook, Kelsava war zufrieden. Er wird die Legende heraussuchen und uns dann in der Gruppe berichten.

info: letsDiscoverRuins
condcode: Npc_IsDead(SteelGolem1)
flags: important
<So, das wäre erledigt. Ich glaube, ich sehe den Eingang.
<Wir sollten uns drinnen umsehen. Vielleicht finden wir noch einen Hinweis auf diese Zwischenwelt.
$LOGMISS theOldCiv, Der Weg ist frei. Das Öl und die Zauber machen tatsächlich einen Unterschied. Mal sehen, ob wir in den Ruinen etwas finden.
!changeRoutineTemple(1);
!FF_Remove(ffFollowPlayerPort);

info: smallTalkTemple
conddia: letsDiscoverRuins
condcode: Npc_IsInState(self, ZS_TALK)
condcode: knowsCandleBook == FALSE
flags: important, permanent
<Soviel zu entdecken und so wenig Zeit...
$END

info: foudCandleBook
conddia: letsDiscoverRuins
condcode: knowsCandleBook
>Ich habe da ein interessantes Buch gefunden?
<Achja? Was ist denn daran so besonders?
>Abgesehen davon, dass ich nichts lesen kann? Auf einer Seite ist eine Kerze abgebildet.
>Also... eingemeißelt. Sind schließlich nur Steintafeln...
<Das ist wirklich auffällig. Welcher Buchständer ist es?
>Der rechts neben dem Gitter, vor dem Zaphina steht.
<Natürlich der eine, den ich mir noch nicht angesehen habe... Ich schau mal nach. Bis gleich!
!Npc_ExchangeRoutine(self, "BOOKSTAND");
!AI_Standup(self);

info: readCandleBook
conddia: letsDiscoverRuins
condcode: KelsavaCandleBook
desc: Hast du etwas herausgefunden?
>Und? Was herausgefunden?
<Wie mans nimmt...
<Diese Schriftzeichen habe ich bereits schon einmal in einigen Büchern in unserer Bibliothek gelesen.
<Ich verstehe nicht viel davon, denn wir konnten bisher nur weniges übersetzen. Aber...
<Wenn ich richtig lese, dann steht hier tatsächlich eine Art Ritual beschrieben, mit dem der Übertritt in die Zwischenwelt gelingen soll.
>Meinst du etwa...
<Sollten wir dieses Ritual durchführen können, dann könnten wir das Übel an der Wurzel bekämpfen.
<Ich werde versuchen, ein eigenes Ritual zu entwickeln. Denn einige der genannten Begriffe konnte ich zwar übersetzen, allerdings habe ich noch nie etwas davon gehört.
<Stromgenerator... Was auch immer das sein soll. Also müssen wir selbst etwas basteln.
<Ich werde einige Zeit brauchen und definitiv Thiralas Hilfe.
<Ich würde vorschlagen, wir treffen uns in zwei Tagen bei unseren Türmen. Bis dahin haben wir bestimmt etwas entwickelt.
<Oder wenigstens herausgefunden...
$LOGMISS theOldCiv, Kelsava meint, das Buch enthalte eine Art Ritual, welches den Übertritt in die Zwischenwelt ermöglichen soll. Er und Thirala wollen es für unsere Voraussetzungen anpassen. In zwei Tagen wollen wir uns wieder treffen.
!ritualDay = Wld_GetDay();
!changeRoutineTemple(2);

info: foundRitual
conddia: readCandleBook
condcode: Wld_GetDay() >= ritualDay + 2
condcode: Npc_GetDistToWP(self, "NW_CASTLEMINE_HUT_03") <= 500
>Habt ihr ein Ritual entwickeln können?
<Das haben wir in der Tat.
<Aber... 
>War ja klar.
<Es gibt immer ein Aber. Manchmal ein kleineres, manchmal ein größeres.
<Und hierbei...
>Lass mich raten. Es ist größer?
<Wir, das heißt Thirala und ich, können immer nur eine Person in die andere Welt schicken.
<Danach müssen wir wieder entsprechende Materialien für den Übergang bereitstellen.
<Dazu muss ein Kristall mit genügend Äther aufge...
<Entschuldige, ich will dich nicht damit langweilen.
<Fakt ist: Es dauert wenigstens einen Tag. Wenn wir dich als erstes schicken, bist du einige Zeit auf dich allein gestellt.
<Anders geht es leider nicht...
<Bist du bereit, alleine zu gehen?
$LOGMISS theOldCiv, Kelsava und Thirala haben es geschafft ein Ritual, ähnlich dem der alten Zivilisation zu entwickeln.
$MISSUCC theOldCiv
$STARTMIS theRitual
$LOGMISS theRitual, Das Ritual hat einen Nachteil: Ich kann nur alleine überwechseln. Doch wenn wir die Bedrohung nur so beseitigen können, geht es nicht anders.
!showRitualVobs();

%

opt: yes
>Ich bin bereit!
<Das ist gut. Wir haben das Ritual im anderen Turm vorbereitet.
<Triff mich dort, dann erkläre ich dir alles weitere!
!toldRitualYes = TRUE;
!changeRoutineTemple(3);

%%

opt: notYet
>Noch nicht.
<In Ordnung, das kann ich verstehen.
<Bereite dich vor, dann komm wieder her.
<Wir können das Ritual jederzeit durchführen.

%%

info: readyForRit
conddia: foundRitual
condcode: toldRitualYes == FALSE
flags: permanent
>Ich bin bereit für das Ritual!
<Sehr gut. Triff mich im anderen Turm, da haben wir das Ritual vorbereitet.
<Alles weitere erkläre ich dir dort!
!toldRitualYes = TRUE;
!changeRoutineTemple(3);

info: doTheRitual1
condcode: toldRitualYes
condcode: Npc_GetDistToWP(self, "NW_CASTLEMINE_TOWER_08") <= 200
>Ein Pentagramm? Ernsthaft?
<(lacht) Das ist eigentlich gar nicht so wichtig. Es kommt nur darauf an, dass wir uns gleichmäßig verteilen können.
<Thirala und ich werden die Magie aktiv bündeln. Fyneia ist als dritter Fixpunkt mit dabei.
<Sobald du in der Mitte stehst, können wir anfangen. Denn dort bündelt sich der Äther und wird dich in die Zwischenwelt bringen.
<Bist du bereit?

info: doTheRitual2
conddia: doTheRitual1
>Ich bin bereit!
<Sehr gut. Dann tritt in die Mitte und wir fangen an.
!AI_GotoWP(hero, "NW_CASTLEMINE_RITUAL_MIDDLE_000");
!AI_TurnToNPC(hero, self);
!AI_TurnToNPC(self, hero);
$END
!AI_StartState(self, ZS_RitualLevelchange, 1, "");

info: youreBack
conddia: NONE_10000_Hueter, hesGone
flags: important
<Nanu? Schon wieder zurück? Dann hat es wohl nicht funktioniert...
>Was soll das heißen? Ich war bestimmt eine Stunde weg.
<Du warst keine ZWEI Sekunden weg. Oder...
>Die Zeit...
<Was ist damit?
>Die Zeit scheint dort anders zu verlaufen. Wie auch immer: Ich brauche eure Hilfe!
<Worum geht es?
>Jemand ist in die Zwischenwelt eingedrungen und hindert die Seelen am Übertritt. Wir müssen ihn festsetzen und daran hindern.
>Doch das schaffe ich nicht allein. Er scheint sich zu teleportieren und...
<Ja, das ist schwer zu verhindern. Ich denke, da wird sich etwas ergeben. Doch erst einmal müssen wir alle hinüberwechseln.
>Aber... Das Ritual ist doch nur für eine Person ausgelegt.
<Jetzt, wo wir wissen, dass es funktioniert, können wir es ausweiten. Dafür müssen wir nur die Magie weiter bündeln. Und ich habe auch schon eine Idee, wie wir das anstellen.

info: whatToGet
conddia: youreBack
>Was brauchst du?
<(lacht) Klar, dass ich dir nichts vormachen kann.
<Folgendes: Ich habe von magischen Experimenten auf dem Festland gehört. Dabei wollten die Magier wohl eine Art Barriere erschaffen, die Menschen daran hindert, in einen Ort einzudringen.
<Oder herauszukommen? Ich weiß es ehrlich gesagt nicht mehr genau. Was ich allerdings noch weiß:
<Um die Barriere aufzubauen, müssen sie die Magie ebenfalls bündeln. Dafür wollten sie sogenannte Fokussteine verwenden.
<Vielleicht können wir welche herstellen. Du müsstest mir nur die Materialien besorgen.
>Nochmal: Was brauchst du?
<Wir sind fünf Leute, also fünf Fokussteine. Für jeden von ihnen brauche ich vier Aquamarine und zwei Brocken Silbererz.
<Beides muss nicht veredelt werden, von mir aus kannst du es auch direkt aus dem Berg holen.
<Oder du siehst bei den Händlern nach, ob sie etwas auf Lager haben.
$STARTMIS theFocus
$LOGMISS theFocus, Kelsava möchte die Magie des Rituals weiter bündeln, um uns alle in die Zwischenwelt zu bringen. Dafür braucht er Hilfsmittel, die er Fokussteine nennt, für jeden von uns einen. Insgesamt braucht er dafür zwanzig Aquamarine und zehn Brocken Silbererz.
<Du findest mich in der Bibliothek des Klosters.
!Npc_ExchangeRoutine(KDF_1409_Kelsava, "START");
!Npc_ExchangeRoutine(KDW_14009_Thirala, "LIBRARY");
$IF Npc_GetTrueGuild(hero) == GIL_SLD
!Npc_ExchangeRoutine(VLK_4007_Fyneia, "STARTSLD");
$ELSE
!Npc_ExchangeRoutine(VLK_4007_Fyneia, "START");
$ENDIF
!Npc_ExchangeRoutine(BAU_241_Zaphina, "GROUPCAMP");

info: gotItems
condcode: gotQuestItemsFocus()
conddia: whatToGet
>Ich habe die Sachen, die du brauchst!
<Das ist sehr gut!
!giveQuestItemsFocus(self, other);
<<ItMi_Silver_Nugget, 10
<Wunderbar. Dann kann ich gleich anfangen.
<Ich werde einen Tag brauchen. Dann können wir weitermachen.
$LOGMISS theFocus, Ich habe Kelsava die Rohstoffe gebracht. Er wird die Fokussteine herstellen, das dauert allerdings einen Tag.
!kelsavaFocusDay = Wld_GetDay();

info: focusReady
conddia: gotItems
condcode: Wld_GetDay() >= kelsavaFocusDay + 1
>Sind die Fokussteine fertig?
<Sind sie. Hier, nimm du sie und bring den anderen jeweils einen.
<<ItMi_Focus, 4
<Wir treffen uns wieder in unserem Turm.
$LOGMISS theFocus, Kelsava hat die Foki hergestellt. Ich soll sie den anderen bringen. Wir treffen uns dann wieder in unserem Turm.
!Npc_ExchangeRoutine(self, "RITUAL");

info: shouldGoBack
condcode: startedLastChange == FALSE
conddia: PAL_5000_Marten, gotAPlan
>Wir sollten zurückkehren!
<Bist du sicher? Das wird kein Zuckerschlecken!
<Ich gehe schonmal vor. Wenn du wirklich bereit bist, sag den anderen Bescheid.
<Wir treffen uns wieder auf dem Berg.
!Npc_ExchangeRoutine(self, "RITUAL");
!startedLastChange = TRUE;
!LastChangeKelsava = TRUE;

info: weGoBack
condcode: startedLastChange == TRUE && LastChangeKelsava == FALSE
>Es geht los!
<Alles klar. Wir sollten keine Zeit mehr verlieren.
<Der Äther wird mit jeder Minute die wir warten, weiter zerstört.
<Noch ist der Schaden reversibel.
>Dann sehen wir uns im Turm!
!Npc_ExchangeRoutine(self, "RITUAL");